Accessing Files on a Network

To access a file on a remote system, you include the node name in the file specification of the external file you identify for the execution of the program. For example:

BOSTON::DBA0:[MALCOLM]TEMPS.TST

This file specification identifies the file TEMPS.TST in the directory [MALCOLM] on the device DBA0: on the node BOSTON.

You can specify a node name in a file specification in either of the following contexts:

For example:

OPEN FILE (NETFILE) SEQUENTIAL INPUT RECORD
      TITLE
('TULSA::DBB0:[MALCOLM]PLITEST.DAT');

This OPEN statement specifies the name of a file to be read from the node named TULSA.

If no file specification is present in the TITLE option, or if the TITLE option specifies a logical name, you can define a remote file. For example:

OPEN FILE(INFILE) INPUT RECORD SEQUENTIAL;

This OPEN statement refers to the logical name INFILE. The following DEFINE command equates this logical name with a remote file:

$ DEFINE INFILE TULSA::DBB0:[MALCOLM]PL1TEST.DAT

When the OPEN statement is executed, the run-time system associates the remote file with the PL/I file INFILE.

When you run a program that modifies a file on a remote node in a protected account, the file specification must contain an access control string. Each VSI operating system defines the format of an access control string. For an OpenVMS system, you specify the user name and password of the account whose file you are modifying. For example:

$ DEFINE INFILE -
$_TULSA“"MALCOLM YES"""::DBB0:[ENERGY]PL1TEST.DAT”

The user name MALCOLM and the password for this account (YES) are enclosed in quotation marks following the node name in the file specification. The extra quotation marks are required because the DCL command interpreter removes single pairs of quotation marks from lines. On the system at the node TULSA, the user MALCOLM must have access privileges to the account ENERGY.

The following file-system functions are not available for processing remote files: keyed statements (DELETE, WRITE, REWRITE FILE_ID_TO, FILE_ID_FROM, RECORD_ID_TO, and RECORD_ID_FROM) cannot be followed by a sequential operation; that is, an operation that does not specify a key.

Network task-to-task communication lets a program running on one network node interact with a program running on another network node. The interaction is accomplished with PL/I I/O statements, but network connections themselves are transparent to the cooperating programs.

PL/I programs at remote locations can communicate over the network by the following mechanism:

Examples 14.1 and 14.2 illustrate PL/I programs that communicate across the network using synchronous I/O. The following notes are keyed to Example 14.1, “A PL/I Network Source Task”:

SOURCE_TASK: PROCEDURE;    /* ❶ */

    DECLARE TASKNAME FILE;

    DECLARE 1 TASK_MESSAGE,
              2 NUMBER FIXED BINARY(31),
              2 TEXT CHARACTER(40) VARYING;

    ON UNDEFINEDFILE(TASKNAME) BEGIN;    /* ❷ */
        PUT SKIP LIST('File error',ONCODE());
        STOP;
        END;
    OPEN FILE(TASKNAME) SEQUENTIAL OUTPUT RECORD    /* ❸ */
           TITLE('BOSTON"BEANS BAKED"::"TASK=LOGGER"');

    NUMBER = 1;             /* ❹ */
    TEXT = 'first message';
    WRITE FILE (TASKNAME) FROM (TASK_MESSAGE);
    NUMBER = 2;
    TEXT = 'second message';
    WRITE FILE (TASKNAME) FROM (TASK_MESSAGE);
    NUMBER = 3;
    TEXT = 'third and last message';
    WRITE FILE(TASKNAME) FROM (TASK_MESSAGE);

    CLOSE FILE(TASKNAME);      /* ❺ */
    RETURN;

    END;

The following notes are keyed to Example 14.2, “A PL/I Target Task”:

TARGET_TASK: PROCEDURE;   /* ❶ */

    DECLARE (INFILE,OUTFILE) FILE;   /* Files */
    DECLARE 1 LOG_MESSAGE,           /* Structure to read in messages */
              2 STATUS FIXED BIN(31),
              2 TEXT CHARACTER(40) VARYING;
    DECLARE MESSAGE CHARACTER(80);   /* Variable to convert message */

    PUT STRING(MESSAGE) EDIT(' ') (A(80));

    ON UNDEFINEDFILE(INFILE) GOTO FILE_ERROR; /* Network errors */  /* ❷ */

    ON ENDFILE(INFILE) GOTO FINISH;     /* Normal completion */  /* ❸ */

    OPEN FILE (INFILE) RECORD SEQUENTIAL INPUT
            TITLE ('SYS$NET');    /* Open SYS$NET */   /* ❹ */
    OPEN FILE(OUTFILE) RECORD SEQUENTIAL OUTPUT
            TITLE('TASK.DAT');      /* Open output log file */

    LOOP:                                        /* ❺ */
            READ FILE(INFILE) INTO (LOG_MESSAGE);
            PUT STRING(MESSAGE) EDIT(STATUS,TEXT) (F(6),X,A);
            WRITE FILE(OUTFILE) FROM (MESSAGE);
            GOTO LOOP;
    FINISH:
            CLOSE FILE(INFILE);
            CLOSE FILE(OUTFILE);
            RETURN;
    FILE_ERROR:
            PUT SKIP LIST('Input file error',ONCODE());
            RETURN;
    END;